AS/400 Code Samples - AS/400  - WO - GSS Work With Outqs   


Author:		George Pearson 
Company:	Green Springs Software, Inc.
Purpose:	Programmers Utility to Work With the desired list of OutQs.  
                Allows you to use just the 2 letter command, with a 1 character parameter. 
                (OK, I'm a hunt n' pecker typist)
Components:	WO	CMD
              	WO	Program

Parameters:     OutQ   Enter Qualified or Unqualified QutQ Name
Special Values:	*All, *Job, *Libl, *Curlib
Written:	1995


/* ***************************************************************** */         
/*                                                                   */         
/*                 GREEN  SPRINGS  SOFTWARE, INC.                    */         
/*                                                                   */         
/* ***************************************************************** */         
/*                                                                   */         
/*   COMMAND NAME       - WO			AS/400 VERSION       */         
/*   COMMAND PROC PGM.  - WO                                         */         
/*   CREATED BY         - George Pearson, Green Springs Software Inc.*/         
/*   DATE CREATED       -  4/20/95                                   */         
/*                                                                   */         
/*   PURPOSE  -       Work With OutQ.  Default is Job's OutQ         */         
/*   NOTES    -       Executes WO CPP                                */         
/*   Copyright 2002 Green Springs Software, Ashland OR               */         
/*                  (541) 488-2560                                   */         
/*                  www.green-springs.com                            */         
/* ***************************************************************** */ 

             CMD        PROMPT('GSS Work With OutQ')

             PARM       KWD(OUTQ) TYPE(QUAL1)  PROMPT('OutQ +
                          Name to Work With' 10)
 QUAL1:      QUAL       TYPE(*NAME) LEN(10) SPCVAL((*ALL) (*JOB)) DFT(*JOB)
             QUAL       TYPE(*NAME) LEN(10) DFT(*LIBL) SPCVAL((*LIBL) +
                          (*CURLIB)) PROMPT('In Library:')
/* *****  End of Source (WO) Command ****************************** */


/* *********************************************************************/       
/*                                                                     */       
/*     Green Springs Software, Inc.            Ashland, OR             */       
/*                                                                     */       
/* *********************************************************************/       
/*                                                                     */       
/*   PROGRAM ID         - WO                 AS/400 VERSION            */       
/*   DISPLAY FILE NAME  - *None                                        */       
/*   CREATED BY         - George Pearson                               */       
/*   DATE CREATED       -  4/2/95                                      */       
/*                                                                     */       
/*   PURPOSE  -       GSS Work With OutQ                               */       
/*                                                                     */       
/*   NOTES    -       Executed by WO Command.                          */
/*                                                                     */       
/*   (c) 1998 Green Springs Software Inc.                              */       
/*            PO Box 3336,   Ashland,  OR  97520                       */
/*            (541) 488-2560     www.green-springs.com                 */       
/*                                                                     */       
/* *********************************************************************/                                                                                
          PGM        PARM(&OUTQLIB)

             DCL        VAR(&LIB)     TYPE(*CHAR) LEN(10)
             DCL        VAR(&MSG)     TYPE(*CHAR) LEN(80)
             DCL        VAR(&MSGF)    TYPE(*CHAR) LEN(10)
             DCL        VAR(&MSGFLIB) TYPE(*CHAR) LEN(10)
             DCL        VAR(&MSGID)   TYPE(*CHAR) LEN(07)
             DCL        VAR(&OUTQ)    TYPE(*CHAR) LEN(10)
             DCL        VAR(&OUTQLIB) TYPE(*CHAR) LEN(20)

             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ERROR))
             CHGVAR     VAR(&OUTQ) VALUE(%SST(&OUTQLIB  1 10))
             CHGVAR     VAR(&LIB)  VALUE(%SST(&OUTQLIB 11 10))

     /*                                                                     */
     /*    If OutQ is *Job (the Default), Determine what that is            */
     /*    -----------------------------------------------------            */
             IF         COND(&OUTQ = '*JOB') THEN(DO)
                 RTVJOBA    OUTQ(&OUTQ) OUTQLIB(&LIB)
                 IF         COND(&OUTQ = '*DEV') THEN(DO)
                     CHGVAR     VAR(&OUTQ) VALUE('*ALL')
                     GOTO       CMDLBL(DALL)
                 ENDDO
                 WRKOUTQ    OUTQ(&LIB/&OUTQ)
                 RETURN
             ENDDO

     /*                                                                     */
     /*    If OutQ is *All, The Show 'em All!                               */
     /*    ----------------------------------                               */
DALL:        IF         COND(&OUTQ = '*ALL') THEN(DO)
                 WRKOUTQ    OUTQ(*ALL)
                 RETURN
             ENDDO
     /*                                                                     */
     /*    Insert your favorites here! Mine are                             */
     /*    ----------------------------------                               */

             IF         COND(&OUTQ = 'J') THEN(DO)
                 WRKOUTQ    OUTQ(QEZJOBLOG)
                 RETURN
             ENDDO

             IF         COND(&OUTQ = 'G') THEN(DO)
                 WRKOUTQ    OUTQ(GSS/GSS)
                 RETURN
             ENDDO

             IF         COND(&OUTQ = 'P') THEN(DO)
                 WRKOUTQ    OUTQ(PRT01)
                 RETURN
             ENDDO

             IF         COND(&OUTQ = 'S') THEN(DO)
                 WRKOUTQ    OUTQ(QPRINTS)
                 RETURN
             ENDDO

             IF         COND(&OUTQ = 'Q') THEN(DO)
                 WRKOUTQ    OUTQ(QPRINT)
                 RETURN
             ENDDO

             WRKOUTQ    OUTQ(&LIB/&OUTQ)
                 RETURN

 ERROR:      RCVMSG     MSG(&MSG) MSGID(&MSGID) MSGF(&MSGF) +
                          MSGFLIB(&MSGFLIB)
             SNDPGMMSG  MSGID(&MSGID) MSGF(&MSGFLIB/&MSGF) +
                          MSGDTA(&OUTQ *CAT &LIB)

ENDPGM:      ENDPGM

/* ******** End Of Source (WO) CL Program *************************/